feature

(source, CPAN)

version 1.93

You are viewing the version of this documentation from Perl blead. This is a development version of Perl.

NAME
SYNOPSIS
DESCRIPTION
- Lexical effect
- no feature
AVAILABLE FEATURES
FEATURE BUNDLES
IMPLICIT LOADING
CHECKING FEATURES

#NAME

feature - Perl pragma to enable new features

#SYNOPSIS

use feature qw(fc say);

# Without the "use feature" above, this code would not be able to find
# the built-ins "say" or "fc":
say "The case-folded version of $x is: " . fc $x;


# set features to match the :5.36 bundle, which may turn off or on
# multiple features (see "FEATURE BUNDLES" below)
use feature ':5.36';


# implicitly loads :5.36 feature bundle
use v5.36;

#DESCRIPTION

It is usually impossible to add new syntax to Perl without breaking some existing programs. This pragma provides a way to minimize that risk. New syntactic constructs, or new semantic meanings to older constructs, can be enabled by use feature 'foo', and will be parsed only when the appropriate feature pragma is in scope. (Nevertheless, the CORE:: prefix provides access to all Perl keywords, regardless of this pragma.)

#Lexical effect

Like other pragmas (use strict, for example), features have a lexical effect. use feature qw(foo) will only make the feature "foo" available from that point to the end of the enclosing block.

{
    use feature 'say';
    say "say is available here";
}
print "But not here.\n";

#`no feature`

Features can also be turned off by using no feature "foo". This too has lexical effect.

use feature 'say';
say "say is available here";
{
    no feature 'say';
    print "But not here.\n";
}
say "Yet it is here.";

no feature with no features specified will reset to the default group. To disable all features (an unusual request!) use no feature ':all'.

#AVAILABLE FEATURES

Read "FEATURE BUNDLES" for the feature cheat sheet summary.

#The 'say' feature

use feature 'say' tells the compiler to enable the Raku-inspired say function.

See "say" in perlfunc for details.

This feature is available starting with Perl 5.10.

#The 'state' feature

use feature 'state' tells the compiler to enable state variables.

See "Persistent Private Variables" in perlsub for details.

This feature is available starting with Perl 5.10.

#The 'switch' feature

use feature 'switch' told the compiler to enable the Raku given/when construct.

This feature was removed in Perl 5.42.

#The 'unicode_strings' feature

use feature 'unicode_strings' tells the compiler to use Unicode rules in all string operations executed within its scope (unless they are also within the scope of either use locale or use bytes). The same applies to all regular expressions compiled within the scope, even if executed outside it. It does not change the internal representation of strings, but only how they are interpreted.

no feature 'unicode_strings' tells the compiler to use the traditional Perl rules wherein the native character set rules is used unless it is clear to Perl that Unicode is desired. This can lead to some surprises when the behavior suddenly changes. (See "The "Unicode Bug"" in perlunicode for details.) For this reason, if you are potentially using Unicode in your program, the use feature 'unicode_strings' subpragma is strongly recommended.

This feature is available starting with Perl 5.12; was almost fully implemented in Perl 5.14; and extended in Perl 5.16 to cover quotemeta; was extended further in Perl 5.26 to cover the range operator; and was extended again in Perl 5.28 to cover special-cased whitespace splitting.

#The 'unicode_eval' and 'evalbytes' features

Together, these two features are intended to replace the legacy string eval function, which behaves problematically in some instances. They are available starting with Perl 5.16, and are enabled by default by a use 5.16 or higher declaration.

unicode_eval changes the behavior of plain string eval to work more consistently, especially in the Unicode world. Certain (mis)behaviors couldn't be changed without breaking some things that had come to rely on them, so the feature can be enabled and disabled. Details are at "Under the "unicode_eval" feature" in perlfunc.

evalbytes is like string eval, but it treats its argument as a byte string. Details are at "evalbytes EXPR" in perlfunc. Without a use feature 'evalbytes' nor a use v5.16 (or higher) declaration in the current scope, you can still access it by instead writing CORE::evalbytes.

#The 'current_sub' feature

This provides the __SUB__ token that returns a reference to the current subroutine or undef outside of a subroutine.

This feature is available starting with Perl 5.16.

#The 'array_base' feature

This feature supported the legacy $[ variable. See "$[" in perlvar. It was on by default but disabled under use v5.16 (see "IMPLICIT LOADING", below) and unavailable since perl 5.30.

This feature is available under this name starting with Perl 5.16. In previous versions, it was simply on all the time, and this pragma knew nothing about it.

#The 'fc' feature

use feature 'fc' tells the compiler to enable the fc function, which implements Unicode casefolding.

See "fc" in perlfunc for details.

This feature is available from Perl 5.16 onwards.

#The 'lexical_subs' feature

In Perl versions prior to 5.26, this feature enabled declaration of subroutines via my sub foo, state sub foo and our sub foo syntax. See "Lexical Subroutines" in perlsub for details.

This feature is available from Perl 5.18 onwards. From Perl 5.18 to 5.24, it was classed as experimental, and Perl emitted a warning for its usage, except when explicitly disabled:

no warnings "experimental::lexical_subs";

As of Perl 5.26, use of this feature no longer triggers a warning, though the experimental::lexical_subs warning category still exists (for compatibility with code that disables it). In addition, this syntax is not only no longer experimental, but it is enabled for all Perl code, regardless of what feature declarations are in scope.

#The 'postderef' and 'postderef_qq' features

The 'postderef_qq' feature extends the applicability of postfix dereference syntax so that postfix array dereference, postfix scalar dereference, and postfix array highest index access are available in double-quotish interpolations. For example, it makes the following two statements equivalent:

my $s = "[@{ $h->{a} }]";
my $s = "[$h->{a}->@*]";

This feature is available from Perl 5.20 onwards. In Perl 5.20 and 5.22, it was classed as experimental, and Perl emitted a warning for its usage, except when explicitly disabled:

no warnings "experimental::postderef";

As of Perl 5.24, use of this feature no longer triggers a warning, though the experimental::postderef warning category still exists (for compatibility with code that disables it).

The 'postderef' feature was used in Perl 5.20 and Perl 5.22 to enable postfix dereference syntax outside double-quotish interpolations. In those versions, using it triggered the experimental::postderef warning in the same way as the 'postderef_qq' feature did. As of Perl 5.24, this syntax is not only no longer experimental, but it is enabled for all Perl code, regardless of what feature declarations are in scope.

#The 'signatures' feature

This enables syntax for declaring subroutine arguments as lexical variables. For example, for this subroutine:

sub foo ($left, $right) {
    return $left + $right;
}

Calling foo(3, 7) will assign 3 into $left and 7 into $right.

See "Signatures" in perlsub for details.

This feature is available from Perl 5.20 onwards. From Perl 5.20 to 5.34, it was classed as experimental, and Perl emitted a warning for its usage, except when explicitly disabled:

no warnings "experimental::signatures";

As of Perl 5.36, use of this feature no longer triggers a warning, though the experimental::signatures warning category still exists (for compatibility with code that disables it). This feature is now considered stable, and is enabled automatically by use v5.36 (or higher).

#The 'refaliasing' feature

WARNING: This feature is still experimental and the implementation may change or be removed in future versions of Perl. For this reason, Perl will warn when you use the feature, unless you have explicitly disabled the warning:

no warnings "experimental::refaliasing";

This enables aliasing via assignment to references:

\$a = \$b; # $a and $b now point to the same scalar
\@a = \@b; #                     to the same array
\%a = \%b;
\&a = \&b;
foreach \%hash (@array_of_hash_refs) {
    ...
}

See "Assigning to References" in perlref for details.

This feature is available from Perl 5.22 onwards.

#The 'bitwise' feature

This makes the four standard bitwise operators (& | ^ ~) treat their operands consistently as numbers, and introduces four new dotted operators (&. |. ^. ~.) that treat their operands consistently as strings. The same applies to the assignment variants (&= |= ^= &.= |.= ^.=).

See "Bitwise String Operators" in perlop for details.

This feature is available from Perl 5.22 onwards. Starting in Perl 5.28, use v5.28 will enable the feature. Before 5.28, it was still experimental and would emit a warning in the "experimental::bitwise" category.

#The 'declared_refs' feature

no warnings "experimental::declared_refs";

This allows a reference to a variable to be declared with my, state, or our, or localized with local. It is intended mainly for use in conjunction with the "refaliasing" feature. See "Declaring a Reference to a Variable" in perlref for examples.

This feature is available from Perl 5.26 onwards.

#The 'isa' feature

This allows the use of the isa infix operator, which tests whether the scalar given by the left operand is an object of the class given by the right operand. See "Class Instance Operator" in perlop for more details.

This feature is available from Perl 5.32 onwards. From Perl 5.32 to 5.34, it was classed as experimental, and Perl emitted a warning for its usage, except when explicitly disabled:

no warnings "experimental::isa";

As of Perl 5.36, use of this feature no longer triggers a warning (though the experimental::isa warning category still exists for compatibility with code that disables it). This feature is now considered stable, and is enabled automatically by use v5.36 (or higher).

#The 'indirect' feature

This feature allows the use of indirect object syntax for method calls, e.g. new Foo 1, 2;. It is enabled by default, but can be turned off to disallow indirect object syntax.

This feature is available under this name from Perl 5.32 onwards. In previous versions, it was simply on all the time. To disallow (or warn on) indirect object syntax on older Perls, see the indirect CPAN module.

#The 'multidimensional' feature

This feature enables multidimensional array emulation, a perl 4 (or earlier) feature that was used to emulate multidimensional arrays with hashes. This works by converting code like $foo{$x, $y} into $foo{join($;, $x, $y)}. It is enabled by default, but can be turned off to disable multidimensional array emulation.

When this feature is disabled the syntax that is normally replaced will report a compilation error.

This feature is available under this name from Perl 5.34 onwards. In previous versions, it was simply on all the time.

You can use the multidimensional module on CPAN to disable multidimensional array emulation for older versions of Perl.

#The 'bareword_filehandles' feature

This feature enables bareword filehandles for builtin functions operations, a generally discouraged practice. It is enabled by default, but can be turned off to disable bareword filehandles, except for the exceptions listed below.

The perl built-in filehandles STDIN, STDOUT, STDERR, DATA, ARGV, ARGVOUT and the special _ are always enabled.

This feature is available under this name from Perl 5.34 onwards. In previous versions it was simply on all the time.

You can use the bareword::filehandles module on CPAN to disable bareword filehandles for older versions of perl.

#The 'try' feature

WARNING: This feature is still partly experimental, and the implementation may change or be removed in future versions of Perl.

This feature enables the try and catch syntax, which allows exception handling, where exceptions thrown from the body of the block introduced with try are caught by executing the body of the catch block.

This feature is available starting in Perl 5.34. Before Perl 5.40 it was classed as experimental, and Perl emitted a warning for its usage, except when explicitly disabled:

no warnings "experimental::try";

As of Perl 5.40, use of this feature without a finally block no longer triggers a warning. The optional finally block is still considered experimental and emits a warning, except when explicitly disabled as above.

For more information, see "Try Catch Exception Handling" in perlsyn.

#The 'defer' feature

no warnings "experimental::defer";

This feature enables the defer block syntax, which allows a block of code to be deferred until when the flow of control leaves the block which contained it. For more details, see "defer" in perlsyn.

This feature is available starting in Perl 5.36.

#The 'extra_paired_delimiters' feature

no warnings "experimental::extra_paired_delimiters";

This feature enables the use of more paired string delimiters than the traditional four, < >, ( ), { }, and [ ]. When this feature is on, for example, you can say qr«pat».

As with any usage of non-ASCII delimiters in a UTF-8-encoded source file, you will want to ensure the parser will decode the source code from UTF-8 bytes with a declaration such as use utf8.

This feature is available starting in Perl 5.36.

For a full list of the available characters, see "List of Extra Paired Delimiters" in perlop.

#The 'module_true' feature

This feature removes the need to return a true value at the end of a module loaded with require or use. Any errors during compilation will cause failures, but reaching the end of the module when this feature is in effect will prevent perl from throwing an exception that the module "did not return a true value".

#The 'class' feature

no warnings "experimental::class";

This feature enables the class block syntax and other associated keywords which implement the "new" object system, previously codenamed "Corinna".

#The 'apostrophe_as_package_separator' feature

This feature enables use ' (apostrophe) as an alternative to using :: as a separate in package and other global names.

This is enabled by default, but disabled from the 5.41 feature bundle onwards. In previous versions it was enabled all the time.

This only disables ' in symbols in your source code, the internal conversion from ' to ::, including for symbolic references, is always enabled.

#The 'any' feature

no warnings "experimental::any";

This feature enables the any operator keyword. This allow testing whether any of the values in a list satisfy a given condition, with short-circuiting behaviour as soon as it finds one.

#The 'all' feature

no warnings "experimental::all";

This feature enables the all operator keyword. This allow testing whether all of the values in a list satisfy a given condition, with short-circuiting behaviour as soon as it finds one that does not.

Note: remember that this enables one specific feature whose name is all; it does not enable all of the features. This is not use feature ':all'. For that, see the section below.

#FEATURE BUNDLES

It's possible to load multiple features together, using a feature bundle. The name of a feature bundle is prefixed with a colon, to distinguish it from an actual feature.

use feature ":5.10";

The following feature bundles are available:

bundle    features included
--------- -----------------
:default  indirect multidimensional
          bareword_filehandles
          apostrophe_as_package_separator

:5.10     apostrophe_as_package_separator
          bareword_filehandles indirect
          multidimensional say state

:5.12     apostrophe_as_package_separator
          bareword_filehandles indirect
          multidimensional say state unicode_strings

:5.14     apostrophe_as_package_separator
          bareword_filehandles indirect
          multidimensional say state unicode_strings

:5.16     apostrophe_as_package_separator
          bareword_filehandles current_sub evalbytes
          fc indirect multidimensional say state
          unicode_eval unicode_strings

:5.18     apostrophe_as_package_separator
          bareword_filehandles current_sub evalbytes
          fc indirect multidimensional say state
          unicode_eval unicode_strings

:5.20     apostrophe_as_package_separator
          bareword_filehandles current_sub evalbytes
          fc indirect multidimensional say state
          unicode_eval unicode_strings

:5.22     apostrophe_as_package_separator
          bareword_filehandles current_sub evalbytes
          fc indirect multidimensional say state
          unicode_eval unicode_strings

:5.24     apostrophe_as_package_separator
          bareword_filehandles current_sub evalbytes
          fc indirect multidimensional postderef_qq
          say state unicode_eval unicode_strings

:5.26     apostrophe_as_package_separator
          bareword_filehandles current_sub evalbytes
          fc indirect multidimensional postderef_qq
          say state unicode_eval unicode_strings

:5.28     apostrophe_as_package_separator
          bareword_filehandles bitwise current_sub
          evalbytes fc indirect multidimensional
          postderef_qq say state unicode_eval
          unicode_strings

:5.30     apostrophe_as_package_separator
          bareword_filehandles bitwise current_sub
          evalbytes fc indirect multidimensional
          postderef_qq say state unicode_eval
          unicode_strings

:5.32     apostrophe_as_package_separator
          bareword_filehandles bitwise current_sub
          evalbytes fc indirect multidimensional
          postderef_qq say state unicode_eval
          unicode_strings

:5.34     apostrophe_as_package_separator
          bareword_filehandles bitwise current_sub
          evalbytes fc indirect multidimensional
          postderef_qq say state unicode_eval
          unicode_strings

:5.36     apostrophe_as_package_separator
          bareword_filehandles bitwise current_sub
          evalbytes fc isa postderef_qq say signatures
          state unicode_eval unicode_strings

:5.38     apostrophe_as_package_separator bitwise
          current_sub evalbytes fc isa module_true
          postderef_qq say signatures state
          unicode_eval unicode_strings

:5.40     apostrophe_as_package_separator bitwise
          current_sub evalbytes fc isa module_true
          postderef_qq say signatures state try
          unicode_eval unicode_strings

:5.42     bitwise current_sub evalbytes fc isa
          module_true postderef_qq say signatures
          state try unicode_eval unicode_strings

The :default bundle represents the feature set that is enabled before any use feature or no feature declaration.

Specifying sub-versions such as the 0 in 5.14.0 in feature bundles has no effect. Feature bundles are guaranteed to be the same for all sub-versions.

use feature ":5.14.0";    # same as ":5.14"
use feature ":5.14.1";    # same as ":5.14"

You can also do:

use feature ":all";

no feature ":all";

but the first may enable features in a later version of Perl that change the meaning of your code, and the second may disable mechanisms that are part of Perl's current behavior that have been turned into features, just as indirect and bareword_filehandles were.

#IMPLICIT LOADING

Instead of loading feature bundles by name, it is easier to let Perl do implicit loading of a feature bundle for you.

There are two ways to load the feature pragma implicitly:

By using the -E switch on the Perl command-line instead of -e. That will enable the feature bundle for that version of Perl in the main compilation unit (that is, the one-liner that follows -E).
By explicitly requiring a minimum Perl version number for your program, with the use VERSION construct. That is,
```
use v5.36.0;
```
will do an implicit
```
no feature ':all';
use feature ':5.36';
```
and so on. Note how the trailing sub-version is automatically stripped from the version.

But to avoid portability warnings (see "use" in perlfunc), you may prefer:
```
use 5.036;
```
with the same effect.

If the required version is older than Perl 5.10, the ":default" feature bundle is automatically loaded instead.

Unlike use feature ":5.12", saying use v5.12 (or any higher version) also does the equivalent of use strict; see "use" in perlfunc for details.

#CHECKING FEATURES

feature provides some simple APIs to check which features are enabled.

These functions cannot be imported and must be called by their fully qualified names. If you don't otherwise need to set a feature you will need to ensure feature is loaded with:

use feature ();

#feature_enabled($feature)

#feature_enabled($feature, $depth)

package MyStandardEnforcer;
use feature ();
use Carp "croak";
sub import {
  croak "disable indirect!" if feature::feature_enabled("indirect");
}

Test whether a named feature is enabled at a given level in the call stack, returning a true value if it is. $depth defaults to 1, which checks the scope that called the scope calling feature::feature_enabled().

croaks for an unknown feature name.

#features_enabled()

#features_enabled($depth)

package ReportEnabledFeatures;
use feature "say";
sub import {
  say STDERR join " ", feature::features_enabled();
}

Returns a list of the features enabled at a given level in the call stack. $depth defaults to 1, which checks the scope that called the scope calling feature::features_enabled().

#feature_bundle()

#feature_bundle($depth)

Returns the feature bundle, if any, selected at a given level in the call stack. $depth defaults to 1, which checks the scope that called the scope calling feature::feature_bundle().

Returns an undefined value if no feature bundle is selected in the scope.

The bundle name returned will be for the earliest bundle matching the selected bundle, so:

use feature ();
use v5.12;
BEGIN { print feature::feature_bundle(0); }

will print 5.11.

This returns internal state, at this point use v5.12; sets the feature bundle, but use feature ":5.12"; does not set the feature bundle. This may change in a future release of perl.

CONTENTS

#NAME

#SYNOPSIS

#DESCRIPTION

#Lexical effect

#no feature

#AVAILABLE FEATURES

#The 'say' feature

#The 'state' feature

#The 'switch' feature

#The 'unicode_strings' feature

#The 'unicode_eval' and 'evalbytes' features

#The 'current_sub' feature

#The 'array_base' feature

#The 'fc' feature

#The 'lexical_subs' feature

#The 'postderef' and 'postderef_qq' features

#The 'signatures' feature

#The 'refaliasing' feature

#The 'bitwise' feature

#The 'declared_refs' feature

#The 'isa' feature

#The 'indirect' feature

#The 'multidimensional' feature

#The 'bareword_filehandles' feature

#The 'try' feature

#The 'defer' feature

#The 'extra_paired_delimiters' feature

#The 'module_true' feature

#The 'class' feature

#The 'apostrophe_as_package_separator' feature

#The 'any' feature

#The 'all' feature

#FEATURE BUNDLES

#IMPLICIT LOADING

#CHECKING FEATURES

#`no feature`