Wikidata

Gerd Fahrenhorst

Joined 23 February 2013
Babel user information
de-N Dieser Benutzer spricht Deutsch als Muttersprache.
en-2 This user has intermediate knowledge of English.
Users by language
Gerd Fahrenhorst

About me

edit

Siehe auch

edit

ToDo

edit
edit

Nearby ohne Stolpersteine, Straßen und Sonderausstellungen

edit

The following query uses these:

  • Properties: coordinate location (P625)     , instance of (P31)     , located in the administrative territorial entity (P131)     , OpenStreetMap way ID (P10689)     , OpenStreetMap node ID (P11693)     , location (P276)     
    SELECT ?place ?dist ?placeLabel ?placeDescription ?istEinLabel ?liegtInLabel ?ortLabel ?OsmLi ?OsmKn
WHERE
{
  # Nearby ohne Stolpersteine, Straßen und Sonderausstellungen
  wd:Q2204038 wdt:P625 ?loc . # irgendein Item mit Geokoordinaten
  #BIND ( "Point(-79.71 15.8)"^^geo:wktLiteral AS ?loc ) . # Beliebige Position. Erst Ost/West. keine Blanks vor oder nach den Koordinaten!
  SERVICE wikibase:around {
      ?place wdt:P625 ?location .
      bd:serviceParam wikibase:center ?loc .
      bd:serviceParam wikibase:radius "5" .
  }
  OPTIONAL { ?place wdt:P31 ?istEin }
  OPTIONAL { ?place wdt:P131 ?liegtIn }
  OPTIONAL { ?place wdt:P10689 ?OsmLi }
  OPTIONAL { ?place wdt:P11693 ?OsmKn }
  OPTIONAL { ?place wdt:P276  ?ort }
  FILTER ( ?istEin != wd:Q26703203 && ?istEin != wd:Q29023906 && ?istEin != wd:Q79007 )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  BIND(geof:distance(?loc, ?location) as ?dist)
} ORDER BY ?dist
LIMIT 50
Try it!

Nearby mit Denkmal Nds und OSM, ohne Stolpersteine

edit

The following query uses these:

Try it!

Unvollständig

edit

Nearby, mit Geokoordinaten aber ohne P31 (ist ein) oder ohne P17 (Staat)

edit

Hier muss man sorgfältig ein ODER Zeichen "||" bei der FILTER Anweisung vermeiden, damit das SPARQL2 Template die FILTER Zeile verarbeiten kann.

The following query uses these:

  • Properties: coordinate location (P625)     , instance of (P31)     , located in the administrative territorial entity (P131)     , country (P17)     
    SELECT ?place ?dist ?placeLabel ?placeDescription ?istEinLabel ?liegtInLabel
WHERE
{
  wd:Q494631 wdt:P625 ?loc . # Objekt mit Geokoordinaten
  #BIND ( "Point(-79.71 15.8)"^^geo:wktLiteral AS ?loc ) . # Beliebige Position. Erst Ost/West. keine Blanks vor oder nach den Koordinaten!
  SERVICE wikibase:around {
      ?place wdt:P625 ?location .
      bd:serviceParam wikibase:center ?loc .
      bd:serviceParam wikibase:radius "20" .
  }
  OPTIONAL { ?place wdt:P31 ?istEin }
  OPTIONAL { ?place wdt:P131 ?liegtIn }
  OPTIONAL { ?place wdt:P17 ?staat }
  FILTER ( ! (BOUND(?istEin ) && BOUND(?staat )) ) # nur wenn kein P31 oder P17 angegeben
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  BIND(geof:distance(?loc, ?location) as ?dist)
} ORDER BY ?dist
LIMIT 50
Try it!

Nearby, mit Geokoordinaten aber ohne "ist ein", "Staat" oder "liegt in"

edit

Hier muss man sorgfältig ein ODER Zeichen "||" bei der FILTER Anweisung vermeiden, damit das SPARQL2 Template die FILTER Zeile verarbeiten kann.

The following query uses these:

  • Properties: coordinate location (P625)     , instance of (P31)     , located in the administrative territorial entity (P131)     , country (P17)     
    SELECT ?place ?dist ?placeLabel ?placeDescription ?istEinLabel ?liegtInLabel
WHERE
{
  # Nearby, mit Geokoordinaten aber ohne "ist ein", Staat oder "liegt in"
  wd:Q494631 wdt:P625 ?loc . # Objekt mit Geokoordinaten
  #BIND ( "Point(-79.71 15.8)"^^geo:wktLiteral AS ?loc ) . # Beliebige Position. Erst Ost/West. keine Blanks vor oder nach den Koordinaten!
  SERVICE wikibase:around {
      ?place wdt:P625 ?location .
      bd:serviceParam wikibase:center ?loc .
      bd:serviceParam wikibase:radius "10" .
  }
  OPTIONAL { ?place wdt:P31 ?istEin }
  OPTIONAL { ?place wdt:P131 ?liegtIn }
  OPTIONAL { ?place wdt:P17 ?staat }
  FILTER ( ! (BOUND(?istEin ) && BOUND(?staat ) && BOUND(?liegtIn )) ) # nur wenn kein P31 oder P17 oder P131 angegeben
  FILTER ( ?istEin != wd:Q26703203 && ?istEin != wd:Q29023906) # keine Stolpersteine und keine Sonderausstellungen
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  BIND(geof:distance(?loc, ?location) as ?dist)
} ORDER BY ?dist
LIMIT 50
Try it!

Schleuse in Deutschland ohne P206 (liegt am Gewässer) oder P131 (liegt in)

edit

Hier muss man sorgfältig ein ODER Zeichen "||" bei der FILTER Anweisung vermeiden, damit das SPARQL2 Template die FILTER Zeile verarbeiten kann.

The following query uses these:

Try it!

Niedersachsen

edit

Hauptverwaltung in Niedersachsen

edit

The following query uses these:

Try it!

Bauwerk in Niedersachsen

edit

The following query uses these:

Try it!

irgendwas in Region Hannover

edit

The following query uses these:

Try it!

liegt in Verwaltungseinheit grafisch

edit

The following query uses these:

Features: map (Q24515275)     

#defaultView:Map
SELECT ?item ?itemLabel ?isteinLabel ?liegtinLabel ?loc WHERE {
  # liegt in der Verwaltungseinheit, oder in einer Einheit die in dieser Verw.Einheit liegt
  ?item wdt:P131/wdt:P131? wd:Q1715.
  ?item wdt:P625 ?loc.
  ?item wdt:P131 ?liegtin.
  ?item wdt:P31 ?istein.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
LIMIT 9000   # Sind (Stand: 7/2022) über 7000 Items
Try it!

liegt in statistischer Einheit grafisch

edit

The following query uses these:

Features: map (Q24515275)     

#defaultView:Map
SELECT ?item ?itemLabel ?isteinLabel ?liegtinLabel ?loc WHERE {
  # liegt in der Verwaltungseinheit, oder in einer Einheit die in dieser Verw.Einheit liegt
  ?item wdt:P8138 wd:Q18615961.
  ?item wdt:P625 ?loc.
  ?item wdt:P131 ?liegtin.
  ?item wdt:P31 ?istein.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
LIMIT 9000   # Sind (Stand: 7/2022) über 7000 Items
Try it!

Zierbrunnen in der Umgebung eines Ortes

edit

The following query uses these:

Features: map (Q24515275)     

#defaultView:Map
SELECT ?place ?location ?placeLabel ?placeDescription ?istEinLabel ?liegtInLabel ?pic
WHERE
{
  wd:Q1055 wdt:P625 ?loc . # Q1055=Hamburg, Q1715=Hannover, muss mit Geokoord. sein
  SERVICE wikibase:around {
      ?place wdt:P625 ?location .
      bd:serviceParam wikibase:center ?loc .
      bd:serviceParam wikibase:radius "20" .
  }
  OPTIONAL { ?place wdt:P31 ?istEin }
  OPTIONAL { ?place wdt:P131 ?liegtIn }
  OPTIONAL { ?place wdt:P17 ?staat }
  OPTIONAL { ?place wdt:P18 ?pic }
  #FILTER ( ?placeLabel == "Brunnen" ) # funktioniert nicht ?!
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
  FILTER ( ?istEin = wd:Q483453 )   # Q483453 ist Zierbrunnen, Q43483 Wasserbrunnen
  BIND(geof:distance(?loc, ?location) as ?dist)
} ORDER BY ?dist
LIMIT 150
Try it!

Standorte der Kupferhäuser

edit

The following query uses these:

Features: map (Q24515275)     

#defaultView:Map
SELECT ?item ?itemLabel ?liegtinLabel ?loc WHERE {
  # ist ein Kupferhaus
  ?item wdt:P31 wd:Q1306182.
  ?item wdt:P625 ?loc.
  ?item wdt:P131 ?liegtin.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
}
LIMIT 90
Try it!

Werke eines Künstlers

edit

Werke von C. W. Allers

edit

The following query uses these:

  • Properties: author (P50)     , illustrator (P110)     , creator (P170)     , instance of (P31)     , inception (P571)     , image (P18)     
    SELECT ?objekt ?objektLabel ?objektDescription ?istEinLabel ?autorLabel ?illustLabel ?urheberLabel ?pic ?jahr
WHERE
{
  VALUES ?wasSuchenWir { wdt:P50 wdt:P110 wdt:P170 }  # Autor, Illustrator oder Urheber
  ?objekt  ?wasSuchenWir wd:Q704689.    # Q704689 = C. W. Allers
  OPTIONAL { ?objekt  wdt:P31  ?istEin }
  OPTIONAL { ?objekt  wdt:P50  ?autor }
  OPTIONAL { ?objekt  wdt:P110 ?illust }
  OPTIONAL { ?objekt  wdt:P170 ?urheber }
  OPTIONAL { ?objekt  wdt:P571 ?datum; BIND(YEAR(?datum) AS ?jahr) }
  OPTIONAL { ?objekt  wdt:P18  ?pic }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
} ORDER BY ?objektLabel 
LIMIT 150
Try it!

Werke von Andreas Rimkus

edit

The following query uses these:

Features: map (Q24515275)     

#defaultView:Map
SELECT ?objekt ?objektLabel ?objektDescription ?istEinLabel ?liegtInLabel ?pic ?jahr ?loc ?osm
WHERE
{
  ?objekt  wdt:P170 wd:Q500247 . # P170 = Urheber, Q500247 = Andreas Rimkus
  OPTIONAL { ?objekt  wdt:P31  ?istEin }
  OPTIONAL { ?objekt  wdt:P131 ?liegtIn }
  OPTIONAL { ?objekt  wdt:P625 ?loc }
  OPTIONAL { ?objekt  wdt:P571 ?datum; BIND(YEAR(?datum) AS ?jahr) }
  OPTIONAL { ?objekt  wdt:P18  ?pic }
  OPTIONAL { ?objekt  wdt:P11693 ?osm }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de" }
} ORDER BY ?objektLabel 
LIMIT 50  # 17 in 411 ms (Oktober 2023)
Try it!

Werke von Diether Heisig

edit

The following query uses these:

Features: ImageGrid (Q24515278)     

# #defaultView:ImageGrid
SELECT ?item ?itemLabel ?istEinLabel ?itemDescription ?liegtinLabel ?pic ?loc ?jahr ?osm
WHERE {
  ?item wdt:P170 wd:Q63929521.   # Urheber ist Diether Heisig
  ?item wdt:P31 ?istEin.
  OPTIONAL { ?item wdt:P625 ?loc }
  OPTIONAL { ?item wdt:P131 ?liegtin }
  OPTIONAL { ?item wdt:P571 ?datum; BIND(YEAR(?datum) AS ?jahr) }
  OPTIONAL { ?item wdt:P18 ?pic }
  OPTIONAL { ?item wdt:P11693 ?osm }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "de,en". }
} ORDER BY ?datum 
LIMIT 50  # 40 in 530 ms (Oktober 2023)
Try it!

Werke von Hartmut Wiesner

edit

The following query uses these:

Try it!

Skulpturen, Zierbrunnen, Denkmäler u.ä. nach Ort

edit

Siehe User:Gerd Fahrenhorst/KunstNachOrt.

Objekte mit Vanderkrogt-ID

edit

Objekte in Niedersachsen mit Vanderkrogt-ID

edit

The following query uses these:

Try it!

Objekte in Hamburg mit Vanderkrogt-ID

edit

The following query uses these:

Try it!

Straßen in Kiel

edit

The following query uses these:

Try it!
Retrieved from "https://www.wikidata.org/w/index.php?title=User:Gerd_Fahrenhorst&oldid=2241691310"