Wikidata:WikiProject every politician/Bulgaria
Jump to navigation
Jump to search
Try it!
Try it!
Try it!
Try it!
- Head of State: Rumen Radev (President of Bulgaria)
- Head of Government: Nikolay Denkov (Prime Minister of Bulgaria)
- Legislature: National Assembly of Bulgaria
- Executive: Government of Bulgaria
See also Wikidata:WikiProject_Bulgaria
National Legislature
[edit]| Legislature | Seats | Status | ||||
|---|---|---|---|---|---|---|
| National Assembly of Bulgaria (Q639704) | 240 | See completeness indicators for current members | ||||
| ||||||
Gender statistics of National Assembly of Bulgaria (Q639704) by term
[edit]#defaultView:BarChart
select ?nsLabel (COUNT(distinct ?x) as ?mps) ?sexLabel ?NUM {
?ns p:P31 [ps:P31 wd:Q43792361 ; pq:P1545 ?num]
bind(strdt(?num,xsd:integer) as ?NUM)
filter(?NUM >= 39)
?x p:P39 [ps:P39 wd:Q18924508 ; pq:P2937 ?ns] ; wdt:P21 ?sex .
SERVICE wikibase:label { bd:serviceParam wikibase:language "bg".
?ns rdfs:label ?nsLabel .
?sex rdfs:label ?sexLabel .
}
} group by ?nsLabel ?sexLabel ?NUM order by desc(?NUM)
Composition by group of National Assembly of Bulgaria (Q639704)
[edit]#defaultView:BarChart
select ?nsLabel (COUNT(distinct ?x) as ?mps) ?groupLabel {
?ns p:P31 [ps:P31 wd:Q43792361 ; pq:P1545 ?num]
bind(strdt(?num,xsd:integer) as ?NUM)
filter(?NUM >= 39)
?x p:P39 [ps:P39 wd:Q18924508 ; pq:P2937 ?ns ; pq:P4100 ?group] .
SERVICE wikibase:label { bd:serviceParam wikibase:language "bg".
?ns rdfs:label ?nsLabel .
?group rdfs:label ?groupLabel .
}
} group by ?nsLabel ?groupLabel
MPs elected from their native district
[edit]This query selects only MPs from the 48th national assembly, which are born (place of birth (P19) in the constituency of the National Assembly of Bulgaria (Q43791141) from which they are elected. Sofia (Q472) is excluded due to the particularity of the electoral map there
select * {
?ns p:P31 [ps:P31 wd:Q43792361 ; pq:P1545 "48"] .
?mp p:P39 [ps:P39 wd:Q18924508 ; pq:P2937 ?ns ; pq:P768 ?mir] ; wdt:P19 ?pob.
?pob wdt:P131*/wdt:P7938 ?mir .
SERVICE wikibase:label { bd:serviceParam wikibase:language "bg".
?mp rdfs:label ?mpLabel .
?ns rdfs:label ?nsLabel .
?mir rdfs:label ?mirLabel .
?pob rdfs:label ?pobLabel .
}
}
MPs of 49th National Assembly without articles in the wikipedia.bg
[edit]SELECT ?itemLabel ?article WHERE {
?item wdt:P31 wd:Q5; p:P39 ?statement .
?statement ps:P39 wd:Q18924508 ; pq:P2937 wd:Q117600091 .
MINUS {
?article schema:about ?item ;
schema:isPartOf <https://bg.wikipedia.org/> .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}