SQL Server Dynamic SQL - Get output from list of tables

Question

I am trying to loop through a temp table variable that contains a list of table names. I want to simply count the rows in each table where a DateTracked column is greater than 30 days. I am having trouble dynamically changing the FROM @tblName variable to store the record count and then insert it into my tracking table. Eventually I will use a cursor to loop through each, but I just want to get this logic down first for a single table. Here is my test code:

DECLARE @tblName as NVARCHAR(MAX)
DECLARE @q as NVARCHAR(MAX)
SET @q = 'Select Count(DateTracked) FROM Audit.' + @tblName + ' WHERE DateTracked > DATEADD(dd, -30, CAST(GETDATE() as date))'

--DECLARE @tblNameTable TABLE
--(
--  tableName NVARCHAR(MAX)
--)
--INSERT INTO @tblNameTable VALUES (N'myTestTable')

DECLARE @ExpectedRecordsToMove AS TABLE (col1 int)
INSERT INTO @ExpectedRecordsToMove EXECUTE sp_executesql @q, N'@tblName nvarchar(500)', @tblName = 'myTestTable'

SELECT * FROM @ExpectedRecordsToMove

Answer 1

Found solution.

DECLARE @tblName as NVARCHAR(MAX) = 'tblAutoDispatch_DispatchStatus_Map_Tracking'
DECLARE @q as NVARCHAR(MAX) = 'SELECT Count(DateTracked) FROM Audit.' + @tblName + ' WHERE DateTracked > DATEADD(dd, -30, CAST(GETDATE() as date))'

DECLARE @ExpectedRecordsToMove TABLE
(
    ExpectedRecordsToMove Int
)
INSERT INTO @ExpectedRecordsToMove
EXECUTE sp_executesql @q

SELECT * FROM @ExpectedRecordsToMove

_{Note: Answer provided by OP on question.}

Answer 2

sp_executesql also allows for output parameters. It is possible to assign variable inside the inner query and return the value.

DECLARE @tblName AS NVARCHAR(MAX) = N'tblAutoDispatch_DispatchStatus_Map_Tracking';
DECLARE @q AS NVARCHAR(MAX)
    = N'SELECT @rowcount = COUNT(DateTracked) FROM Audit.' + @tblName
      + N' WHERE DateTracked > DATEADD(dd, -30, CAST(GETDATE() as date))';

DECLARE @rowcount INT;

EXECUTE sp_executesql
    @query = @q,
    @parameters = N'@rowcount INT OUTPUT',
    @rowcount = @rowcount OUTPUT;

SELECT
    @rowcount;

Answer 3

You can actually do this without a cursor, by building up the query in one go

• You must use QUOTENAME to ensure table names do not cause syntax errors
• You cannot parameterize a table name, it must be inserted directly into dynamic SQL

DECLARE @tablenames TABLE (schemaName sysname, tblName sysname);
--  insert schema and table names

DECLARE @sql nvarchar(max) = N'
SELECT
    ISNULL(tblName, ''Grand Total'') AS tblName,
    SUM(rowcount) AS rowcount
FROM (
' +
(
  SELECT STRING_AGG(CAST(
N'    SELECT ' + QUOTENAME(tn.schemaName, '''') + N'.' + QUOTENAME(tn.tblName, '''') + N' AS tblName,
           Count(DateTracked) AS rowCount
    FROM ' + QUOTENAME(tn.schemaName) + N'.' + QUOTENAME(tn.tblName) + N'
    WHERE DateTracked > DATEADD(dd, -30, CAST(GETDATE() as date))'
  AS nvarchar(max)), N'
UNION ALL
')
  FROM @tablenames tn
  JOIN sys.tables t ON tn.schemaName = SCHEMA_NAME(t.schema_id) AND tn.tblName = t.name
) + N'
) AS tables
GROUP BY ROLLUP(tblName);
';

PRINT @sql;  -- for testing
EXEC (@sql);

• If you don't have STRING_AGG on your version of SQL Server, you must use FOR XML instead