Wikipedija

Datoteka:Lagrangian points equipotential.gif

Lagrangian_points_equipotential.gif (512 × 384 piksela, veličina datoteke: 2 MB, MIME tip: image/gif, animacija se ponavlja, 72 okvira, 7,2 s)


Logo Wikimedijinog spremnika Ova se datoteka nalazi na Zajedničkom poslužitelju i mogu je rabiti drugi projekti. Ispod je prikazan opis s njezine tamošnje stranice.

Sažetak

Opis
English: Animation showing the relationship between the five Lagrangian points (red) of a planet (blue) orbiting a star (yellow), and the gravitational potential in the plane containing the orbit (grey surface with purple contours of equal potential). The potential was computed in POV-Ray using

for q = 0.1 and z = 0.[1]
Izvor Vlastito djelo postavljača
Autor cmglee
Ostale inačice
Lagrangian points equipotential.png
Lagrangian points equipotential.jpg
Roche potential.stl

POV-Ray source code

Lagrangian_points_equipotential.pov Lagrangian_points_equipotential.ini 
#declare rotation = clock;
// #declare rotation = -28;
#declare bounding_radius = 8;
#declare q = 0.1;
#declare q_plus_1 = q + 1;
#declare q_divide_q_plus_1 = q / q_plus_1;
#declare two_divide_q_plus_1 = 2 / q_plus_1;

union {
 isosurface {
  function {
   y + (pow(x-q_divide_q_plus_1,2) + z*z + two_divide_q_plus_1 * (q / sqrt((x-1)*(x-1)+z*z) + 1 / sqrt(x*x + z*z)))
  } 
  accuracy     0.001
  max_gradient 200 // increase to reduce artifact in funnel
  contained_by {sphere{0,bounding_radius}} open
  pigment {
   gradient <0,1,0>
   color_map {                                               [0.01 color rgb <0.5,0,0.75>][0.02 color rgb 1]
              [0.18 color rgb 1][0.19 color rgb <0.75,0.5,1>][0.21 color rgb <0.75,0.5,1>][0.22 color rgb 1]
              [0.38 color rgb 1][0.39 color rgb <0.75,0.5,1>][0.41 color rgb <0.75,0.5,1>][0.42 color rgb 1]
              [0.58 color rgb 1][0.59 color rgb <0.75,0.5,1>][0.61 color rgb <0.75,0.5,1>][0.62 color rgb 1]
              [0.78 color rgb 1][0.79 color rgb <0.75,0.5,1>][0.81 color rgb <0.75,0.5,1>][0.82 color rgb 1]
              [0.98 color rgb 1][0.99 color rgb <0.75,0.5,1>]                                               }
   scale 0.5
   translate <0,0.03,0>
  }
  scale     <1,0.5,1>
  translate <0,1.42,0>
 }
 union {
  sphere {0,0.2          pigment {rgbt <1,1,0,0.5>}   interior {ior 1} finish {specular 1 roughness 0.1} }
  sphere {<1,0,0>,0.1    pigment {rgbt <0,0.5,1,0.5>} interior {ior 1} finish {specular 1 roughness 0.1} }
  sphere {<q/2,0,0>,0.05 pigment {rgb  <0.5,0,0>} }
  union {
   torus    {1-q/2,0.02 translate <q/2,0,0>}
   cylinder {<-0.95,0,0>,<1.35,0,0>,0.02}
   cylinder {<q/2,0,0>,<0.5,0,0.866>,0.02}
   cylinder {<q/2,0,0>,<0.5,0,-0.866>,0.02}
   pigment  {rgb <0,0.75,0>}
  }
  union {
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L1" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.72,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L2" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <1.35,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L3" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <-0.95,0,0> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L4" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,0.866> }
   union { sphere {0,0.05} cylinder {0,<0,-9,0>,0.02} text {ttf "arlrdbd.ttf" "L5" 0.2, -0.1 scale 0.4 translate <-0.15,0.05,-0.1> rotate <55,rotation,0> no_shadow} translate <0.5,0,-0.866> }
   pigment {rgb <1,0,0>}
  }
 }
 translate <-q/2,-0.14,0>
 rotate    <0,-rotation,0>
}
sky_sphere {pigment {rgb 1}}
light_source {<0,1,0>    color rgb 0.5 parallel point_at 0}
light_source {<0,10,-10> color rgb 1   shadowless}
camera {orthographic location <0.05,7.8,-10> look_at <0.05,-0.1,0> angle 13.8}

Antialias=off
Antialias_Threshold=0.01
Antialias_Depth=2

Input_File_Name="Lagrangian_points_equipotential.pov"

Initial_Frame=0
Final_Frame=71
Initial_Clock=0
Final_Clock=360

Cyclic_Animation=on
Pause_when_Done=off
  1. ↑ ZF Seidov, "The Roche Problem: Some Analytics", The Astrophysical Journal, 603:283-284, 2004 March 1

Licencija

Ja, nositelj autorskog prava za ovo djelo, ovime ga objavljujem pod sljedećim licencijama:
w:hr:Creative Commons
imenovanje autora dijeli pod istim uvjetima
Ova datoteka je licencirana pod Creative Commons Imenovanje-Dijeli pod istim uvjetima 3.0 nelokaliziranom licencijom.
Slobodno smijete:
  • dijeliti – umnožavati, distribuirati i javnosti priopćavati djelo
  • remiksirati – prerađivati djelo
Pod sljedećim uvjetima:
  • imenovanje autora – Morate pripisati odgovarajuće autorske zasluge, dati poveznicu na licenciju, te naznačiti jesu li načinjene promjene autorskog djela. Prethodno navedeno možete učiniti na svaki razuman način, ali ne na način koji bi sugerirao da Vi ili Vaše korištenje licencorova djela ima izravno licencorovo odobrenje.
  • dijeli pod istim uvjetima – Ako ovo djelo izmijenite, preoblikujete ili stvarate na osnovu tog materijala, svoje doprinose morate distribuirati pod istom ili kompatibilnom licencijom kao što je i licencija originala.
GNU head Dozvoljava se umnožavanje, dijeljenje i/ili mijenjanje ovog dokumenta pod uvjetima GNU-ove licence za slobodnu dokumentaciju, inačica 1.2 ili kasnija ako ju je objavio Free Software Foundation; bez nepromjenjivih ili obveznih dijelova i bez teksta na naslovnoj i/ili posljednjoj stranici. Kopija licencije je uključena u odjeljak naslovljen GNU-ove licence za slobodnu dokumentaciju.
Možete odabrati licenciju prema vašem izboru.

Opisi

Dodajte kratko objašnjenje što predstavlja ova datoteka

Predmeti prikazani u ovoj datoteci

motiv

Povijest datoteke

Kliknite na datum/vrijeme kako biste vidjeli datoteku kakva je tada bila.

Datum/VrijemeMinijaturaDimenzijeSuradnikKomentar
sadašnja00:57, 23. listopada 2021.Minijatura za inačicu od 00:57, 23. listopada 2021.512 × 384 (2 MB)CmgleeIncrease resolution and framerate, rotate around barycentre, reframe image and make bodies transparent
11:35, 16. veljače 2013.Minijatura za inačicu od 11:35, 16. veljače 2013.256 × 192 (709 KB)CmgleeUse 6-bit GIFs.
11:06, 16. veljače 2013.Minijatura za inačicu od 11:06, 16. veljače 2013.256 × 192 (574 KB)CmgleeFix shifting background colour.
10:51, 16. veljače 2013.Minijatura za inačicu od 10:51, 16. veljače 2013.256 × 192 (574 KB)CmgleeOrbit around barycentre instead of Sun, darken every fifth contour and double number of frames.
00:41, 16. veljače 2013.Minijatura za inačicu od 00:41, 16. veljače 2013.256 × 192 (354 KB)Cmglee{{Information |Description ={{en|1=Animation showing the relationship between the five Lagrangian points (red) of a planet (blue) orbiting a star (yellow), and the gravitational potential in the plane containing the orbit (grey surface with purple c...

Nijedna stranica ne rabi ovu datoteku.

Globalna uporaba datoteke

Sljedeći wikiji rabe ovu datoteku:

Metapodatci

Ova datoteka sadržava dodatne podatke koje je vjerojatno dodala digitalna kamera ili skener u procesu snimanja odnosno digitalizacije. Ako je datoteka mijenjana, podatci možda nisu u skladu sa stvarnim stanjem.

Dobavljeno iz "https://hr.wikipedia.org/wiki/Datoteka:Lagrangian_points_equipotential.gif"